home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 007 / yield.bas (.txt) < prev   
Encoding:
GW-BASIC  |  1984-04-24  |  1.1 KB  |  54 lines
  1. 10  REM THIS PROGRAM CALCULATES YIELD OF 
  2. 20  REM SEMICONDUCTOR WAFERS
  3. 30  REM
  4. 40  PI=3.14159
  5. 50  REM SET DEFAULT VARIABLES
  6. 60  WAFSIZ=3
  7. 70  NMASKS=6
  8. 80  DEFDEN=6
  9. 90  EDGE=0.2
  10. 95  COST=100
  11. 100  REM
  12. 110  REM SHOW DEFAULTS AND GET USER DATA
  13. 120  CLS
  14. 130  LOCATE 1,1
  15. 140  PRINT
  16. 150  PRINT "WAFER SIZE          (" WAFSIZ ")INCH";
  17. 160  INPUT W
  18. 170  IF W<>0 THEN WAFSIZ=W
  19. 180  PRINT
  20. 190  PRINT "CRITICAL MASKS      (" NMASKS ")";
  21. 200  INPUT C
  22. 210  IF C<>0 THEN NMASKS=C
  23. 220  PRINT
  24. 230  PRINT "DEFECT DENSITY      (" DEFDEN ")PER SQ INCH";
  25. 240  INPUT D
  26. 250  IF D<>0 THEN DEFDEN=D
  27. 260  PRINT
  28. 270  PRINT "ENTER CHIP DIMENSIONS IN MILS"
  29. 280  PRINT
  30. 290  INPUT "X=   ",X
  31. 300  INPUT "Y=   ",Y
  32. 310  AREA=X*Y*9.99E-07
  33. 320  IF X>Y THEN DIAG=X*0.000999999 ELSE DIAG=Y*0.000999999
  34. 330  IF DIAG>=EDGE THEN EFFAREA=PI*(WAFSIZ/2-DIAG)^2 ELSE EFFAREA=PI*(WAFSIZ/2-EDGE)^2
  35. 340  GROSS=FIX(EFFAREA/AREA)
  36. 350  NET=GROSS*(1/(1+AREA*DEFDEN)^NMASKS)
  37. 360  NET=FIX(NET)
  38. 370  YIELD=FIX(100*NET/GROSS)
  39. 380  PRINT
  40. 390  PRINT "GROSS DIE PER WAFER  " GROSS
  41. 400  PRINT
  42. 410  PRINT "NET DIE PER WAFER    " NET
  43. 420  PRINT
  44. 430  PRINT "PERCENT YIELD        " YIELD
  45. 440  PRINT
  46. 450  PRINT
  47. 460  PRINT "WAFER COST   (" COST ") DOLLARS";
  48. 470  INPUT DOL
  49. 480  IF DOL<>0 THEN COST=DOL
  50. 490  DIECOST=COST/NET
  51. 500  PRINT
  52. 510  PRINT "DIE COST     ";
  53. 520  PRINT USING "##.####"; DIECOST
  54.